- Qt 6.11
- Qt Quick
- QML Types
- Transition
- Qt 6.11.0 Reference Documentation

# Transition QML Type

Defines animated transitions that occur on state changes. More...

Import Statement: | `import QtQuick`

- List of all members, including inherited members

## Properties

- animations : list<Animation>
- enabled : bool
- from : string
- reversible : bool
- running : bool
- to : string

## Detailed Description

A Transition defines the animations to be applied when a State change occurs.

For example, the following Rectangle has two states: the default state, and an added "moved" state. In the "moved state, the rectangle's position changes to (50, 50). The added Transition specifies that when the rectangle changes between the default and the "moved" state, any changes to the `x` and `y` properties should be animated, using an `Easing.InOutQuad`.

     import QtQuick

     Rectangle {
         id: rect
         width: 100; height: 100
         color: "red"

         MouseArea {
             id: mouseArea
             anchors.fill: parent
         }

         states: State {
             name: "moved"; when: mouseArea.pressed
             PropertyChanges { target: rect; x: 50; y: 50 }
         }

         transitions: Transition {
             NumberAnimation { properties: "x,y"; easing.type: Easing.InOutQuad }
         }
     }

Notice the example does not require to and from values for the NumberAnimation. As a convenience, these properties are automatically set to the values of `x` and `y` before and after the state change; the `from` values are provided by the current values of `x` and `y`, and the `to` values are provided by the PropertyChanges object. If you wish, you can provide to and from values anyway to override the default values.

By default, a Transition's animations are applied for any state change in the parent item. The Transition from and to values can be set to restrict the animations to only be applied when changing from one particular state to another.

Top-level animations within a transition are run in parallel. To run them sequentially, define them within a SequentialAnimation:

     transitions: Transition {
         to: "brighter"
         reversible: true
         SequentialAnimation {
             PropertyAnimation { property: "x"; duration: 1000 }
             ColorAnimation { duration: 1000 }
         }
     }

To define multiple Transitions, specify Item::transitions as a list:

         transitions: [
             Transition {
                 from: "*"; to: "middleRight"
                 NumberAnimation {
                     properties: "x,y";
                     easing.type: Easing.InOutQuad;
                     duration: 2000;
                 }
             },
             Transition {
                 from: "*"; to: "bottomLeft";
                 NumberAnimation {
                     properties: "x,y";
                     easing.type: Easing.InOutQuad;
                     duration: 200;
                 }
             },
             //If any other rectangle is clicked, the icon will return
             //to the start position at a slow speed and bounce.
             Transition {
                 from: "*"; to: "*";
                 NumberAnimation {
                     easing.type: Easing.OutBounce;
                     properties: "x,y";
                     duration: 4000;
                 }
             }
         ]

If multiple Transitions are specified, only a single (best-matching) Transition will be applied for any particular state change. In the example above, if the Rectangle enters a state other than `"middleRight"` or `"bottomLeft"`, the third Transition will be carried out, meaning the icon will be moved to the starting point.

If a state change has a Transition that matches the same property as a Behavior, the Transition animation overrides the Behavior for that state change.

See also Animation and Transitions in Qt Quick, States example, Qt Quick States, and Qt Qml.

## Property Documentation

### animations : list<Animation> `[default]`

This property holds a list of the animations to be run for this transition.

         transitions: Transition {
             PropertyAnimation { duration: 3000 }
             ColorAnimation { duration: 3000 }
         }

The top-level animations are run in parallel. To run them sequentially, define them within a SequentialAnimation:

     transitions: Transition {
         to: "brighter"
         reversible: true
         SequentialAnimation {
             PropertyAnimation { property: "x"; duration: 1000 }
             ColorAnimation { duration: 1000 }
         }
     }

### enabled : bool

This property holds whether the Transition will be run when moving from the `from` state to the `to` state.

By default a Transition is enabled.

Note that in some circumstances disabling a Transition may cause an alternative Transition to be used in its place. In the following example, although the first Transition has been set to animate changes from "state1" to "state2", this transition has been disabled by setting `enabled` to `false`, so any such state change will actually be animated by the second Transition instead.

     Item {
         states: [
             State { name: "state1" },
             State { name: "state2" }
         ]
         transitions: [
             Transition { from: "state1"; to: "state2"; enabled: false },
             Transition {
                 // ...
             }
         ]
     }

### from : string

### to : string

These properties indicate the state changes that trigger the transition.

The default values for these properties is "*" (that is, any state).

For example, the following transition has not set the `to` and `from` properties, so the animation is always applied when changing between the two states (i.e. when the mouse is pressed and released).

     Rectangle {
         id: rect
         width: 100; height: 100
         color: "red"

         MouseArea { id: mouseArea; anchors.fill: parent }

         states: State {
             name: "brighter"; when: mouseArea.pressed
             PropertyChanges { target: rect; color: "yellow" }
         }

         transitions: Transition {
             ColorAnimation { duration: 1000 }
         }
     }

If the transition was changed to this:

     transitions: Transition {
         to: "brighter"
         ColorAnimation { duration: 1000 }
     }

The animation would only be applied when changing from the default state to the "brighter" state (i.e. when the mouse is pressed, but not on release).

Multiple `to` and `from` values can be set by using a comma-separated string.

See also reversible.

### reversible : bool

This property holds whether the transition should be automatically reversed when the conditions that triggered this transition are reversed.

The default value is false.

By default, transitions run in parallel and are applied to all state changes if the from and to states have not been set. In this situation, the transition is automatically applied when a state change is reversed, and it is not necessary to set this property to reverse the transition.

However, if a SequentialAnimation is used, or if the from or to properties have been set, this property will need to be set to reverse a transition when a state change is reverted. For example, the following transition applies a sequential animation when the mouse is pressed, and reverses the sequence of the animation when the mouse is released:

     Rectangle {
         id: rect
         width: 100; height: 100
         color: "steelblue"

         TapHandler { id: tapHandler }

         states: State {
             name: "brighter"
             when: tapHandler.pressed
             PropertyChanges { target: rect; color: "lightsteelblue"; x: 50 }
         }

         transitions: Transition {
             to: "brighter"
             reversible: true
             SequentialAnimation {
                 PropertyAnimation { property: "x"; duration: 1000 }
                 ColorAnimation { duration: 1000 }
             }
         }
     }

If the transition did not set the `to` and `reversible` values, then on the mouse release, the transition would play the PropertyAnimation before the ColorAnimation instead of reversing the sequence.

### running : bool `[read-only]`

This property holds whether the transition is currently running.

Note: Unlike Animation::running, this property is read only, and can not be used to control the transition.