- Qt 6.11
- Qt Quick
- QML Types
- DragHandler
- Qt 6.11.0 Reference Documentation

# DragHandler QML Type

Handler for dragging. More...

Import Statement: | `import QtQuick`
Inherits: | MultiPointHandler

- List of all members, including inherited members
- Deprecated members

## Properties

- acceptedButtons : flags
- acceptedDevices : flags
- acceptedModifiers : flags
- acceptedPointerTypes : flags
- active : bool
- activeTranslation : vector2d
- cursorShape : Qt::CursorShape
- dragThreshold : int
- enabled : bool
- grabPermissions : flags
- margin : real
- parent : Item
- persistentTranslation : vector2d
- snapMode : enumeration
- target : Item
- xAxis
  - xAxis.activeValue : real
  - xAxis.enabled : bool
  - xAxis.maximum : real
  - xAxis.minimum : real
- yAxis
  - yAxis.activeValue : real
  - yAxis.enabled : bool
  - yAxis.maximum : real
  - yAxis.minimum : real

## Signals

- canceled(eventPoint point)
- grabChanged(PointerDevice::GrabTransition transition, eventPoint point)

## Detailed Description

DragHandler is a handler that is used to interactively move an Item. Like other Input Handlers, by default it is fully functional, and manipulates its target.

     import QtQuick

     Rectangle {
         width: 100
         height: 100
         color: "lightsteelblue"
         DragHandler { }
     }

It has properties to restrict the range of dragging.

If it is declared within one Item but is assigned a different target, then it handles events within the bounds of the parent Item but manipulates the `target` Item instead:

     import QtQuick

     Item {
         width: 640
         height: 480

         Rectangle {
             id: feedback
             border.color: "red"
             width: Math.max(10, handler.centroid.ellipseDiameters.width)
             height: Math.max(10, handler.centroid.ellipseDiameters.height)
             radius: Math.max(width, height) / 2
             visible: handler.active
         }

         DragHandler {
             id: handler
             target: feedback
         }
     }

A third way to use it is to set target to `null` and react to property changes in some other way:

     import QtQuick

     Item {
         width: 640
         height: 480

         DragHandler {
             id: handler
             target: null
         }

         Text {
             color: handler.active ? "darkgreen" : "black"
             text: handler.centroid.position.x.toFixed(1) + "," + handler.centroid.position.y.toFixed(1)
             x: handler.centroid.position.x - width / 2
             y: handler.centroid.position.y - height
         }
     }

If minimumPointCount and maximumPointCount are set to values larger than 1, the user will need to drag that many fingers in the same direction to start dragging. A multi-finger drag gesture can be detected independently of both a (default) single-finger DragHandler and a PinchHandler on the same Item, and thus can be used to adjust some other feature independently of the usual pinch behavior: for example adjust a tilt transformation, or adjust some other numeric value, if the `target` is set to null. But if the `target` is an Item, `centroid` is the point at which the drag begins and to which the `target` will be moved (subject to constraints).

DragHandler can be used together with the Drag attached property to implement drag-and-drop.

See also Drag, MouseArea, and Qt Quick Examples - Pointer Handlers.

## Property Documentation

### acceptedButtons : flags

The mouse buttons that can activate this DragHandler.

By default, this property is set to Qt.LeftButton. It can be set to an OR combination of mouse buttons, and will ignore events from other buttons.

For example, if a component (such as TextEdit) already handles left-button drags in its own way, it can be augmented with a DragHandler that does something different when dragged via the right button:

     Rectangle {
         id: canvas
         width: 640
         height: 480
         color: "#333"
         property int highestZ: 0

         Repeater {
             model: FolderListModel { nameFilters: ["*.qml"] }

             delegate: Rectangle {
                 required property string fileName
                 required property url fileUrl
                 required property int index

                 id: frame
                 x: index * 30; y: index * 30
                 width: 320; height: 240
                 property bool dragging: ldh.active || rdh.active
                 onDraggingChanged: if (dragging) z = ++canvas.highestZ
                 border { width: 2; color: dragging ? "red" : "steelblue" }
                 color: "beige"
                 clip: true

                 TextEdit {
                     // drag to select text
                     id: textEdit
                     textDocument.source: frame.fileUrl
                     x: 3; y: 3

                     BoundaryRule on y {
                         id: ybr
                         minimum: textEdit.parent.height - textEdit.height; maximum: 0
                         minimumOvershoot: 200; maximumOvershoot: 200
                         overshootFilter: BoundaryRule.Peak
                     }
                 }

                 DragHandler {
                     id: rdh
                     // right-drag to position the "window"
                     acceptedButtons: Qt.RightButton
                 }

                 WheelHandler {
                     target: textEdit
                     property: "y"
                     onActiveChanged: if (!active) ybr.returnToBounds()
                 }

                 Rectangle {
                     anchors.right: parent.right
                     width: titleText.implicitWidth + 12
                     height: titleText.implicitHeight + 6
                     border { width: 2; color: parent.border.color }
                     bottomLeftRadius: 6
                     Text {
                         id: titleText
                         color: "saddlebrown"
                         anchors.centerIn: parent
                         text: frame.fileName
                         textFormat: Text.PlainText
                     }
                     DragHandler {
                         id: ldh
                         // left-drag to position the "window"
                         target: frame
                     }
                 }
             }
         }
     }

### acceptedDevices : flags

The types of pointing devices that can activate this DragHandler.

By default, this property is set to PointerDevice.AllDevices. If you set it to an OR combination of device types, it will ignore events from non-matching devices.

Note: Not all platforms are yet able to distinguish mouse and touchpad; and on those that do, you often want to make mouse and touchpad behavior the same.

### acceptedModifiers : flags

If this property is set, it will require the given keyboard modifiers to be pressed in order to react to pointer events, and otherwise ignore them.

For example, two DragHandlers can perform two different drag-and-drop operations, depending on whether the `Control` modifier is pressed:

     GridView {
         id: root
         width: 320
         height: 480
         cellWidth: 80
         cellHeight: 80
         interactive: false

         displaced: Transition {
             NumberAnimation {
                 properties: "x,y"
                 easing.type: Easing.OutQuad
             }
         }

         model: DelegateModel {
             id: visualModel
             model: 24
             property var dropTarget: undefined
             property bool copy: false
             delegate: DropArea {
                 id: delegateRoot

                 width: 80
                 height: 80

                 onEntered: drag => {
                     if (visualModel.copy) {
                         if (drag.source !== icon)
                             visualModel.dropTarget = icon
                     } else {
                         visualModel.items.move(drag.source.DelegateModel.itemsIndex, icon.DelegateModel.itemsIndex)
                     }
                 }

                 Rectangle {
                     id: icon
                     objectName: DelegateModel.itemsIndex

                     property string text
                     Component.onCompleted: {
                         color = Qt.rgba(0.2 + (48 - DelegateModel.itemsIndex) * Math.random() / 48,
                                         0.3 + DelegateModel.itemsIndex * Math.random() / 48,
                                         0.4 * Math.random(),
                                         1.0)
                         text = DelegateModel.itemsIndex
                     }
                     border.color: visualModel.dropTarget === this ? "black" : "transparent"
                     border.width: 2
                     radius: 3
                     width: 72
                     height: 72
                     anchors {
                         horizontalCenter: parent.horizontalCenter
                         verticalCenter: parent.verticalCenter
                     }

                     states: [
                         State {
                             when: dragHandler.active || controlDragHandler.active
                             ParentChange {
                                 target: icon
                                 parent: root
                             }

                             AnchorChanges {
                                 target: icon
                                 anchors {
                                     horizontalCenter: undefined
                                     verticalCenter: undefined
                                 }
                             }
                         }
                     ]

                     Text {
                         anchors.centerIn: parent
                         color: "white"
                         font.pointSize: 14
                         text: controlDragHandler.active ? "+" : icon.text
                     }

                     DragHandler {
                         id: dragHandler
                         acceptedModifiers: Qt.NoModifier
                         onActiveChanged: if (!active) visualModel.dropTarget = undefined
                     }

                     DragHandler {
                         id: controlDragHandler
                         acceptedModifiers: Qt.ControlModifier
                         onActiveChanged: {
                             visualModel.copy = active
                             if (!active) {
                                 visualModel.dropTarget.text = icon.text
                                 visualModel.dropTarget.color = icon.color
                                 visualModel.dropTarget = undefined
                             }
                         }
                     }

                     Drag.active: dragHandler.active || controlDragHandler.active
                     Drag.source: icon
                     Drag.hotSpot.x: 36
                     Drag.hotSpot.y: 36
                 }
             }
         }
     }

If this property is set to `Qt.KeyboardModifierMask` (the default value), then the DragHandler ignores the modifier keys.

If you set `acceptedModifiers` to an OR combination of modifier keys, it means all of those modifiers must be pressed to activate the handler.

The available modifiers are as follows:

Constant | Description
--- | ---
`NoModifier` | No modifier key is allowed.
`ShiftModifier` | A Shift key on the keyboard must be pressed.
`ControlModifier` | A Ctrl key on the keyboard must be pressed.
`AltModifier` | An Alt key on the keyboard must be pressed.
`MetaModifier` | A Meta key on the keyboard must be pressed.
`KeypadModifier` | A keypad button must be pressed.
`GroupSwitchModifier` | X11 only (unless activated on Windows by a command line argument). A Mode_switch key on the keyboard must be pressed.
`KeyboardModifierMask` | The handler does not care which modifiers are pressed.

See also Qt::KeyboardModifier.

### acceptedPointerTypes : flags

The types of pointing instruments (finger, stylus, eraser, etc.) that can activate this DragHandler.

By default, this property is set to PointerDevice.AllPointerTypes. If you set it to an OR combination of device types, it will ignore events from non-matching devices.

### active : bool `[read-only]`

This holds `true` whenever this Input Handler has taken sole responsibility for handing one or more eventPoints, by successfully taking an exclusive grab of those points. This means that it is keeping its properties up-to-date according to the movements of those eventPoints and actively manipulating its target (if any).

### activeTranslation : vector2d `[read-only]`

The translation while the drag gesture is being performed. It is `0, 0` when the gesture begins, and increases as the event point(s) are dragged downward and to the right. After the gesture ends, it stays the same; and when the next drag gesture begins, it is reset to `0, 0` again.

### cursorShape : Qt::CursorShape

This property holds the cursor shape that will appear whenever the mouse is hovering over the parent item while active is `true`.

The available cursor shapes are:

- Qt.ArrowCursor
- Qt.UpArrowCursor
- Qt.CrossCursor
- Qt.WaitCursor
- Qt.IBeamCursor
- Qt.SizeVerCursor
- Qt.SizeHorCursor
- Qt.SizeBDiagCursor
- Qt.SizeFDiagCursor
- Qt.SizeAllCursor
- Qt.BlankCursor
- Qt.SplitVCursor
- Qt.SplitHCursor
- Qt.PointingHandCursor
- Qt.ForbiddenCursor
- Qt.WhatsThisCursor
- Qt.BusyCursor
- Qt.OpenHandCursor
- Qt.ClosedHandCursor
- Qt.DragCopyCursor
- Qt.DragMoveCursor
- Qt.DragLinkCursor

The default value is not set, which allows the cursor of parent item to appear. This property can be reset to the same initial condition by setting it to undefined.

Note: When this property has not been set, or has been set to `undefined`, if you read the value it will return `Qt.ArrowCursor`.

See also Qt::CursorShape, QQuickItem::cursor(), and HoverHandler::cursorShape.

### dragThreshold : int

The distance in pixels that the user must drag an eventPoint in order to have it treated as a drag gesture.

The default value depends on the platform and screen resolution. It can be reset back to the default value by setting it to undefined. The behavior when a drag gesture begins varies in different handlers.

### enabled : bool

If a PointerHandler is disabled, it will reject all events and no signals will be emitted.

### grabPermissions : flags

This property specifies the permissions when this handler's logic decides to take over the exclusive grab, or when it is asked to approve grab takeover or cancellation by another handler.

Constant | Description
--- | ---
`PointerHandler.TakeOverForbidden` | This handler neither takes from nor gives grab permission to any type of Item or Handler.
`PointerHandler.CanTakeOverFromHandlersOfSameType` | This handler can take the exclusive grab from another handler of the same class.
`PointerHandler.CanTakeOverFromHandlersOfDifferentType` | This handler can take the exclusive grab from any kind of handler.
`PointerHandler.CanTakeOverFromItems` | This handler can take the exclusive grab from any type of Item.
`PointerHandler.CanTakeOverFromAnything` | This handler can take the exclusive grab from any type of Item or Handler.
`PointerHandler.ApprovesTakeOverByHandlersOfSameType` | This handler gives permission for another handler of the same class to take the grab.
`PointerHandler.ApprovesTakeOverByHandlersOfDifferentType` | This handler gives permission for any kind of handler to take the grab.
`PointerHandler.ApprovesTakeOverByItems` | This handler gives permission for any kind of Item to take the grab.
`PointerHandler.ApprovesCancellation` | This handler will allow its grab to be set to null.
`PointerHandler.ApprovesTakeOverByAnything` | This handler gives permission for any type of Item or Handler to take the grab.

The default is `PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType | PointerHandler.ApprovesTakeOverByAnything` which allows most takeover scenarios but avoids e.g. two PinchHandlers fighting over the same touchpoints.

### margin : real

The margin beyond the bounds of the parent item within which an eventPoint can activate this handler. For example, you can make it easier to drag small items by allowing the user to drag from a position nearby:

     Rectangle {
         width: 24
         height: 24
         border.color: "steelblue"
         Text {
             text: "it's\ntiny"
             font.pixelSize: 7
             rotation: -45
             anchors.centerIn: parent
         }

         DragHandler {
             margin: 12
         }
     }

### parent : Item

The Item which is the scope of the handler; the Item in which it was declared. The handler will handle events on behalf of this Item, which means a pointer event is relevant if at least one of its eventPoints occurs within the Item's interior. Initially target() is the same, but it can be reassigned.

See also target and QObject::parent().

### persistentTranslation : vector2d

The translation to be applied to the target if it is not `null`. Otherwise, bindings can be used to do arbitrary things with this value. While the drag gesture is being performed, activeTranslation is continuously added to it; after the gesture ends, it stays the same.

### snapMode : enumeration

This property holds the snap mode.

The snap mode configures snapping of the target item's center to the eventPoint.

Possible values:

Constant | Description
--- | ---
`DragHandler.NoSnap` | Never snap
`DragHandler.SnapAuto` | The target snaps if the eventPoint was pressed outside of the target item and the target is a descendant of parent item (default)
`DragHandler.SnapWhenPressedOutsideTarget` | The target snaps if the eventPoint was pressed outside of the target
`DragHandler.SnapAlways` | Always snap

### target : Item

The Item which this handler will manipulate.

By default, it is the same as the parent, the Item within which the handler is declared. However, it can sometimes be useful to set the target to a different Item, in order to handle events within one item but manipulate another; or to `null`, to disable the default behavior and do something else instead.

### xAxis group

### xAxis.activeValue : real `[read-only]`

### xAxis.enabled : bool

### xAxis.maximum : real

### xAxis.minimum : real

`xAxis` controls the constraints for horizontal dragging.

`minimum` is the minimum acceptable value of x to be applied to the target. `maximum` is the maximum acceptable value of x to be applied to the target. If `enabled` is true, horizontal dragging is allowed. `activeValue` is the same as activeTranslation.x.

The `activeValueChanged` signal is emitted when `activeValue` changes, to provide the increment by which it changed. This is intended for incrementally adjusting one property via multiple handlers.

### yAxis group

### yAxis.activeValue : real `[read-only]`

### yAxis.enabled : bool

### yAxis.maximum : real

### yAxis.minimum : real

`yAxis` controls the constraints for vertical dragging.

`minimum` is the minimum acceptable value of y to be applied to the target. `maximum` is the maximum acceptable value of y to be applied to the target. If `enabled` is true, vertical dragging is allowed. `activeValue` is the same as activeTranslation.y.

The `activeValueChanged` signal is emitted when `activeValue` changes, to provide the increment by which it changed. This is intended for incrementally adjusting one property via multiple handlers:

     import QtQuick

     Rectangle {
         width: 50; height: 200

         Rectangle {
             id: knob
             width: parent.width; height: width; radius: width / 2
             anchors.centerIn: parent
             color: "lightsteelblue"

             Rectangle {
                 antialiasing: true
                 width: 4; height: 20
                 x: parent.width / 2 - 2
             }

             WheelHandler {
                 property: "rotation"
             }
         }

         DragHandler {
             target: null
             dragThreshold: 0
             yAxis.onActiveValueChanged: (delta)=> { knob.rotation -= delta }
         }
     }

## Signal Documentation

### canceled(eventPoint point)

If this handler has already grabbed the given point, this signal is emitted when the grab is stolen by a different Pointer Handler or Item.

Note: The corresponding handler is `onCanceled`.

### grabChanged(PointerDevice::GrabTransition transition, eventPoint point)

This signal is emitted when the grab has changed in some way which is relevant to this handler.

The transition (verb) tells what happened. The point (object) is the point that was grabbed or ungrabbed.

Valid values for transition are:

Constant | Description
--- | ---
`PointerDevice.GrabExclusive` | This handler has taken primary responsibility for handling the point.
`PointerDevice.UngrabExclusive` | This handler has given up its previous exclusive grab.
`PointerDevice.CancelGrabExclusive` | This handler's exclusive grab has been taken over or cancelled.
`PointerDevice.GrabPassive` | This handler has acquired a passive grab, to monitor the point.
`PointerDevice.UngrabPassive` | This handler has given up its previous passive grab.
`PointerDevice.CancelGrabPassive` | This handler's previous passive grab has terminated abnormally.

Note: The corresponding handler is `onGrabChanged`.