- Qt 6.11
- Qt Quick
- QML Types
- PointHandler
- Qt 6.11.1 Reference Documentation

# PointHandler QML Type

Handler for reacting to a single touchpoint. More...

Import Statement: | `import QtQuick`
Inherits: | SinglePointHandler

- List of all members, including inherited members

## Properties

- acceptedButtons : flags
- acceptedDevices : flags
- acceptedModifiers : flags
- acceptedPointerTypes : flags
- active : bool
- cursorShape : Qt::CursorShape
- enabled : bool
- grabPermissions : flags
- margin : real
- parent : Item
- point : handlerPoint
- target : real

## Signals

- canceled(eventPoint point)
- grabChanged(PointerDevice::GrabTransition transition, eventPoint point)

## Detailed Description

PointHandler can be used to show feedback about a touchpoint or the mouse position, or to otherwise react to pointer events.

When a press event occurs, each instance of PointHandler chooses a single point which is not yet "taken" at that moment: if the press occurs within the bounds of the PointerHandler::parent, and no sibling PointHandler within the same PointerHandler::parent has yet acquired a passive grab on that point, and if the other constraints such as acceptedButtons, acceptedDevices etc. are satisfied, it's eligible, and the PointHandler then acquires a passive grab. In this way, the PointerHandler::parent acts like an exclusive group: there can be multiple instances of PointHandler, and the set of pressed touchpoints will be distributed among them. Each PointHandler which has chosen a point to track has its active property `true`. It then continues to track its chosen point until release: the properties of the point will be kept up-to-date. Any Item can bind to these properties, and thereby follow the point's movements.

By being only a passive grabber, it has the ability to keep independent oversight of all movements. The passive grab cannot be stolen or overridden even when other gestures are detected and exclusive grabs occur.

If your goal is orthogonal surveillance of eventpoints, an older alternative was QObject::installEventFilter(), but that has never been a built-in QtQuick feature: it requires some C++ code, such as a QQuickItem subclass. PointHandler is more efficient than that, because only pointer events will be delivered to it, during the course of normal event delivery in QQuickWindow; whereas an event filter needs to filter all QEvents of all types, and thus sets itself up as a potential event delivery bottleneck.

One possible use case is to add this handler to a transparent Item which is on top of the rest of the scene (by having a high z value), so that when a point is freshly pressed, it will be delivered to that Item and its handlers first, providing the opportunity to take the passive grab as early as possible. Such an item (like a pane of glass over the whole UI) can be a convenient parent for other Items which visualize the kind of reactive feedback which must always be on top; and likewise it can be the parent for popups, popovers, dialogs and so on. If it will be used in that way, it can be helpful for your main.cpp to use QQmlContext::setContextProperty() to make the "glass pane" accessible by ID to the entire UI, so that other Items and PointHandlers can be reparented to it.

     import QtQuick

     Window {
         width: 480
         height: 320
         visible: true

         Item {
             id: glassPane
             z: 10000
             anchors.fill: parent

             PointHandler {
                 id: handler
                 acceptedDevices: PointerDevice.TouchScreen | PointerDevice.TouchPad
                 target: Rectangle {
                     parent: glassPane
                     color: "red"
                     visible: handler.active
                     x: handler.point.position.x - width / 2
                     y: handler.point.position.y - height / 2
                     width: 20; height: width; radius: width / 2
                 }
             }
         }
     }

Like all input handlers, a PointHandler has a target property, which may be used as a convenient place to put a point-tracking Item; but PointHandler will not automatically manipulate the `target` item in any way. You need to use bindings to make it react to the point.

Note: On macOS, PointHandler does not react to multiple fingers on the trackpad by default, although it does react to a pressed point (mouse position). That is because macOS can provide either native gesture recognition, or raw touchpoints, but not both. We prefer to use the native gesture event in PinchHandler, so we do not want to disable it by enabling touch. However MultiPointTouchArea does enable touch, thus disabling native gesture recognition within the entire window; so it's an alternative if you only want to react to all the touchpoints but do not require the smooth native-gesture experience.

See also MultiPointTouchArea, HoverHandler, and Qt Quick Examples - Pointer Handlers.

## Property Documentation

### acceptedButtons : flags

The mouse buttons that can activate this PointHandler.

By default, this property is set to Qt.LeftButton. It can be set to an OR combination of mouse buttons, and will ignore events in which other buttons are pressed or held. If it is set to `Qt.NoButton`, it means it does not care about buttons at all, and ignores synthetic mouse events that come from any device for which it's already handling an authentic eventPoint.

     import QtQuick

     Item {
         width: 480; height: 320

         Rectangle {
             color: handler.active ? "tomato" : "wheat"
             x: handler.point.position.x - width / 2
             y: handler.point.position.y - height / 2
             width: 20; height: width; radius: width / 2
         }

         PointHandler {
             id: handler
             acceptedButtons: Qt.MiddleButton | Qt.RightButton
         }
     }

Note: On a touchscreen, there are no buttons, so this property does not prevent PointHandler from reacting to touchpoints.

Note: By default, when this property holds `Qt.LeftButton`, if a non-mouse PointerDevice (such as a touchscreen or graphics tablet stylus) is allowed to generate synthetic mouse events, those usually indicate that the left mouse button is pressed, and those events can temporarily de-activate the PointHandler which was already reacting to an authentic eventPoint from the device. It's useful to declare

     acceptedButtons: \c Qt.NoButton

to avoid this issue. See also Qt::AA_SynthesizeMouseForUnhandledTouchEvents and Qt::AA_SynthesizeMouseForUnhandledTabletEvents.

### acceptedDevices : flags

The types of pointing devices that can activate this PointHandler.

By default, this property is set to PointerDevice.AllDevices. If you set it to an OR combination of device types, it will ignore events from non-matching devices:

     PointHandler {
         id: handler
         acceptedDevices: PointerDevice.TouchScreen | PointerDevice.TouchPad
         target: Rectangle {
             parent: glassPane
             color: "red"
             visible: handler.active
             x: handler.point.position.x - width / 2
             y: handler.point.position.y - height / 2
             width: 20; height: width; radius: width / 2
         }
     }

### acceptedModifiers : flags

If this property is set, PointHandler requires the given keyboard modifiers to be pressed in order to react to PointerEvents, and otherwise ignores them.

If this property is set to `Qt.KeyboardModifierMask` (the default value), then PointHandler ignores the modifier keys.

For example, an Item could have two handlers, one of which is enabled only if the required keyboard modifier is pressed:

     import QtQuick

     Item {
         id: feedbackPane
         width: 480; height: 320

         PointHandler {
             id: control
             acceptedModifiers: Qt.ControlModifier
             cursorShape: Qt.PointingHandCursor
             target: Rectangle {
                 parent: feedbackPane
                 color: control.active ? "indianred" : "khaki"
                 x: control.point.position.x - width / 2
                 y: control.point.position.y - height / 2
                 width: 20; height: width; radius: width / 2
             }
         }

         PointHandler {
             id: shift
             acceptedModifiers: Qt.ShiftModifier | Qt.MetaModifier
             cursorShape: Qt.CrossCursor
             target: Rectangle {
                 parent: feedbackPane
                 color: shift.active ? "darkslateblue" : "lightseagreen"
                 x: shift.point.position.x - width / 2
                 y: shift.point.position.y - height / 2
                 width: 30; height: width; radius: width / 2
             }
         }
     }

If you set `acceptedModifiers` to an OR combination of modifier keys, it means all of those modifiers must be pressed to activate the handler.

The available modifiers are as follows:

Constant | Description
--- | ---
`NoModifier` | No modifier key is allowed.
`ShiftModifier` | A Shift key on the keyboard must be pressed.
`ControlModifier` | A Ctrl key on the keyboard must be pressed.
`AltModifier` | An Alt key on the keyboard must be pressed.
`MetaModifier` | A Meta key on the keyboard must be pressed.
`KeypadModifier` | A keypad button must be pressed.
`GroupSwitchModifier` | X11 only (unless activated on Windows by a command line argument). A Mode_switch key on the keyboard must be pressed.
`KeyboardModifierMask` | The handler does not care which modifiers are pressed.

See also Qt::KeyboardModifier.

### acceptedPointerTypes : flags

The types of pointing instruments (finger, stylus, eraser, etc.) that can activate this PointHandler.

By default, this property is set to PointerDevice.AllPointerTypes. If you set it to an OR combination of device types, it will ignore events from non-matching devices:

     import QtQuick

     Canvas {
         id: canvas
         width: 800
         height: 600
         antialiasing: true
         renderTarget: Canvas.FramebufferObject
         property var points: []
         onPaint: {
             if (points.length < 2)
                 return
             var ctx = canvas.getContext('2d');
             ctx.save()
             ctx.strokeStyle = stylusHandler.active ? "blue" : "white"
             ctx.lineCap = "round"
             ctx.beginPath()
             ctx.moveTo(points[0].x, points[0].y)
             for (var i = 1; i < points.length; i++)
                 ctx.lineTo(points[i].x, points[i].y)
             ctx.lineWidth = 3
             ctx.stroke()
             points = points.slice(points.length - 2, 1)
             ctx.restore()
         }

         PointHandler {
             id: stylusHandler
             acceptedPointerTypes: PointerDevice.Pen
             onPointChanged: {
                 canvas.points.push(point.position)
                 canvas.requestPaint()
             }
         }

         PointHandler {
             id: eraserHandler
             acceptedPointerTypes: PointerDevice.Eraser
             onPointChanged: {
                 canvas.points.push(point.position)
                 canvas.requestPaint()
             }
         }

         Rectangle {
             width: 10; height: 10
             color: stylusHandler.active ? "green" : eraserHandler.active ? "red" : "beige"
         }
     }

The Qt Quick Examples - Pointer Handlers includes a more complex example for drawing on a Canvas with a graphics tablet.

### active : bool `[read-only]`

This holds `true` whenever the constraints are satisfied and this PointHandler is reacting. This means that it is keeping its properties up-to-date according to the movements of the eventPoints that satisfy the constraints.

### cursorShape : Qt::CursorShape

This property holds the cursor shape that will appear whenever the mouse is hovering over the parent item while active is `true`.

The available cursor shapes are:

- Qt.ArrowCursor
- Qt.UpArrowCursor
- Qt.CrossCursor
- Qt.WaitCursor
- Qt.IBeamCursor
- Qt.SizeVerCursor
- Qt.SizeHorCursor
- Qt.SizeBDiagCursor
- Qt.SizeFDiagCursor
- Qt.SizeAllCursor
- Qt.BlankCursor
- Qt.SplitVCursor
- Qt.SplitHCursor
- Qt.PointingHandCursor
- Qt.ForbiddenCursor
- Qt.WhatsThisCursor
- Qt.BusyCursor
- Qt.OpenHandCursor
- Qt.ClosedHandCursor
- Qt.DragCopyCursor
- Qt.DragMoveCursor
- Qt.DragLinkCursor

The default value is not set, which allows the cursor of parent item to appear. This property can be reset to the same initial condition by setting it to undefined.

Note: When this property has not been set, or has been set to `undefined`, if you read the value it will return `Qt.ArrowCursor`.

See also Qt::CursorShape, QQuickItem::cursor(), and HoverHandler::cursorShape.

### enabled : bool

If a PointerHandler is disabled, it will reject all events and no signals will be emitted.

If a PointerHandler's parent is disabled, the handler will also be effectively disabled, even when the `enabled` property remains `true`.

Note: HoverHandler behaves differently: see the documentation of its enabled property for more information.

### grabPermissions : flags

This property specifies the permissions when this handler's logic decides to take over the exclusive grab, or when it is asked to approve grab takeover or cancellation by another handler.

Constant | Description
--- | ---
`PointerHandler.TakeOverForbidden` | This handler neither takes from nor gives grab permission to any type of Item or Handler.
`PointerHandler.CanTakeOverFromHandlersOfSameType` | This handler can take the exclusive grab from another handler of the same class.
`PointerHandler.CanTakeOverFromHandlersOfDifferentType` | This handler can take the exclusive grab from any kind of handler.
`PointerHandler.CanTakeOverFromItems` | This handler can take the exclusive grab from any type of Item.
`PointerHandler.CanTakeOverFromAnything` | This handler can take the exclusive grab from any type of Item or Handler.
`PointerHandler.ApprovesTakeOverByHandlersOfSameType` | This handler gives permission for another handler of the same class to take the grab.
`PointerHandler.ApprovesTakeOverByHandlersOfDifferentType` | This handler gives permission for any kind of handler to take the grab.
`PointerHandler.ApprovesTakeOverByItems` | This handler gives permission for any kind of Item to take the grab.
`PointerHandler.ApprovesCancellation` | This handler will allow its grab to be set to null.
`PointerHandler.ApprovesTakeOverByAnything` | This handler gives permission for any type of Item or Handler to take the grab.

The default is `PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType | PointerHandler.ApprovesTakeOverByAnything` which allows most takeover scenarios but avoids e.g. two PinchHandlers fighting over the same touchpoints.

### margin : real

The margin beyond the bounds of the parent item within which an eventPoint can activate this handler.

The default value is `0`.

     import QtQuick

     Item {
         width: 480; height: 320

         Rectangle {
             anchors.fill: handlingContainer
             anchors.margins: -handler.margin
             color: "beige"
         }

         Rectangle {
             id: handlingContainer
             width: 200; height: 200
             anchors.centerIn: parent
             border.color: "green"
             color: handler.active ? "lightsteelblue" : "khaki"

             Text {
                 text: "X"
                 x: handler.point.position.x - width / 2
                 y: handler.point.position.y - height / 2
                 visible: handler.active
             }

             PointHandler {
                 id: handler
                 margin: 30
             }
         }

     }

### parent : Item

The Item which is the scope of the handler; the Item in which it was declared. The handler will handle events on behalf of this Item, which means a pointer event is relevant if at least one of its eventPoints occurs within the Item's interior. Initially target() is the same, but it can be reassigned.

See also target and QObject::parent().

### point : handlerPoint `[read-only]`

The eventPoint currently being handled. When no point is currently being handled, this object is reset to default values (all coordinates are 0).

### target : real

A property that can conveniently hold an Item to be manipulated or to show feedback. Unlike other Pointer Handlers, PointHandler does not do anything with the `target` on its own: you usually need to create reactive bindings to properties such as SinglePointHandler::point and PointHandler::active. If you declare an Item instance here, you need to explicitly set its parent, because PointHandler is not an Item.

By default, it is the same as the parent, the Item within which the handler is declared.

## Signal Documentation

### canceled(eventPoint point)

If this handler has already grabbed the given point, this signal is emitted when the grab is stolen by a different Pointer Handler or Item.

Note: The corresponding handler is `onCanceled`.

### grabChanged(PointerDevice::GrabTransition transition, eventPoint point)

This signal is emitted when the grab has changed in some way which is relevant to this handler.

The transition (verb) tells what happened. The point (object) is the point that was grabbed or ungrabbed.

Valid values for transition are:

Constant | Description
--- | ---
`PointerDevice.GrabExclusive` | This handler has taken primary responsibility for handling the point.
`PointerDevice.UngrabExclusive` | This handler has given up its previous exclusive grab.
`PointerDevice.CancelGrabExclusive` | This handler's exclusive grab has been taken over or cancelled.
`PointerDevice.GrabPassive` | This handler has acquired a passive grab, to monitor the point.
`PointerDevice.UngrabPassive` | This handler has given up its previous passive grab.
`PointerDevice.CancelGrabPassive` | This handler's previous passive grab has terminated abnormally.

Note: The corresponding handler is `onGrabChanged`.